如何根據CommandLine去砍掉你要砍的行程?

故事是這樣的: 有一個服務在軟體反安裝時，會將此服務停止並移除。然而，偶爾會發生此服務產生之行程，在軟體移除後依然殘留在系統中。

根據這個問題，有兩個可能: 1. 沒等待服務完全停止就進行移除動作，導致其產生之行程無法正常終止。 2. 這是服務本身的Bug。由於它屬於third-party的軟體，我們也無法去修正它。因此我使用了以下對應措施: 1. 等待服務停止。 2. 等待其產生之行程終止。 3. 再不終止我就讓它終止。

由於此服務產生之行程，並不一定只有我們軟體安裝，使用者也可能自行安裝。因此我們必須針對我們自己的行程去終止。一開始我採用了之前實作的程式，根據它的執行路徑去找到我們所產生的行程並中止。然而，先前的方法並無法順利使用，似乎和行程產生的方式有關係。

好加在有找到WMIC的指令，讓我們能夠從WMI中取得行程的資訊，以達到根據Commmandline過濾行程的目的。但為了寫出這個Batch，可謂一波三折。

我完成的Batch需要調整的變數為PROC_NAME與COND。P_NAME為行程名稱；COND為過濾CommandLine條件，可能是參數或執行路徑中的token。以我的範例來說，我想關閉eclipse.exe所啟動的javaw.exe程式。因此我的PROC_NAME=javaw.exe，COND=eclipse。
Batch內容主要分為兩個Block: 1. 等待行程結束，每檢查一次結果若行程存在就等待一秒再重試。當五次後，行程還沒結束就跳至Block2做Terminate動作。 2. 終結目標行程，透過WMI找到對應之行程並終結。

@echo off
setlocal enabledelayedexpansion
set PROC_NAME=javaw.exe
set COND=eclipse
set CMD_GET_PROC=wmic path win32_process get Processid^^,Caption^^,Commandline ^^^| findstr "^%PROC_NAME%" ^^^| findstr "%COND%"

rem block 1, wait for the process done
set /a "i = 1"
:retry
for /f "usebackq tokens=*" %%r in (`%CMD_GET_PROC%`) do (
if "%%r" == "" goto :finish

set /a "i = i + 1"
if "%i%" == "5" goto :clearProc
timeout /t 1 > NUL
goto :retry
)

rem block 2, terminate the process
:clearProc
set last=
for /f "usebackq tokens=*" %%r in (`%CMD_GET_PROC%`) do (
for %%t in (%%r) do set last=%%t
taskkill /f /pid !!last!
)
:finish

這batch有幾個重點:

1. 將指令執行結果放入變數中: 先前已展試過，這不再提。
2. Retry: 透過Label與Set /a達到。
3. WMIC: 參考這篇範例。這裡需要關注的是過濾行程的方式。
4. 取得字串中最後一個token。
5. 延遲環境變數展開: 因為我不曉得有這東西，也讓我花最多時間的地方。

首先在for loop之前定一個retry label，雖然用goto是不好的行為，但你在batch中不用goto真的做不了什麼事情。接著透過set /a，後面可以接一個expression。如此一來，在每次檢查執行結果後，不符合我就會將i給加1，直到5次才會結束至:clearProc的label，否則會透過timeout的指令做類似sleep的動作。

set /a "i = 1"
:retry
for /f "usebackq tokens=*" %%r in (`%CMD_GET_PROC%`) do (
if "%%r" == "" goto :finish
 
set /a "i = i + 1"
if "%i%" == "5" goto :clearProc
timeout /t 1 > NUL
goto :retry
)
:clearProc

首先透過以下指令取得win32_process中的pid、行程名稱與Commandline內容。pid是為了之後用來做taskkill；行程名稱與Commandline的內容則是用來比對PROC_NAME與COND。

wmic path win32_process get Processid,Caption,Commandline

過濾的部分，必須注意在你下command的同時，也會跟著產生過濾的行程。

javaw.exe                     C:\Windows\system32\javaw.exe -Dosgi.requiredJavaV
ersion=1.5 -Xms40m -Xmx512m -XX:MaxPermSize=256m -jar D:\eclipse_64\plugins/org.
eclipse.equinox.launcher_1.1.0.v20100507.jar -os win32 -ws win32 -arch x86_64 -s
howsplash -launcher D:\eclipse_64\eclipse.exe -name Eclipse --launcher.library D
:\eclipse_64\plugins/org.eclipse.equinox.launcher.win32.win32.x86_64_1.1.0.v2010
0503\eclipse_1307.dll -startup D:\eclipse_64\plugins/org.eclipse.equinox.launche
r_1.1.0.v20100507.jar -exitdata 1df4_58 -product org.eclipse.epp.package.jee.pro
duct -vm C:\Windows\system32\javaw.exe -vmargs -Dosgi.requiredJavaVersion=1.5 -X
ms40m -Xmx512m -XX:MaxPermSize=256m -jar D:\eclipse_64\plugins/org.eclipse.equin
ox.launcher_1.1.0.v20100507.jar
          6876
findstr.exe                   findstr  "javaw.exe"
          6228

因此我透過“^%PROC_NAME%“，去限制顯示結果必須以行程名稱做為開頭(顯示結果順序為 Caption, Commandline, PID)，這樣就可以把findstr給過濾掉了。原先我透過regular expression的方式，但batch支援度不如grep強大，無法做到我想要的結果，才想出這招。

wmic path win32_process get Processid,Caption,Commandline | findstr "^%PROC_NAME%"

由於WMIC所輸出的結果，pid會在最後面，因此我必須要想辦法取得最後面的token。batch的字串處理能力不夠強大，因此我是透過for loop去traverse一個string，最後set的變數值就是最後一個token。

for %%t in (%%r) do set last=%%t

在取得最後一個token後，我遇到最大的問題就是”變數怎麼樣也set不進去”。 對於變數為何一直沒有set至last中，一直百思不解。直到我仔細看過set /?後，才知道了這個東西。看看下面這個範例:

for %%i in (1 2 3 4 5) do (
set var=%%i
echo var=%var%
)

你以為會順利印出var=1至var=5嗎? 你錯了，不信你試試! 問題就出在於: 在迴圈內%var%已經被展開，它會變為在你做set var之前的值，必須用驚嘆號去延遲展開變數。

for %%i in (1 2 3 4 5) do (
set var=%%i
echo var=!!var!
)

要啟用延遲展開變數，可以透過cmd /v或是setlocal enabledelayedexpansion。

由於findstr長度限制為127個字元，假如commandline很長，wmic後的結果一定會有問題。一開始想透過find解決這個問題，但使用後發現難以產生期望輸出。最後是透過WQL去針對commandline與name欄位做過濾，在執行完wmic後，一樣透過findstr去找尋預期程序開頭的行，然後取pid。另外我有針對輸入參數做判斷，程序名稱不得為空，而commandline如果為空就會去砍掉所有輸入名稱的程序。(程序名稱為空會砍掉所有的..)

@echo off
setlocal enabledelayedexpansion
set PROC_NAME=%1
set COND=%2

if "%PROC_NAME%"=="" (
echo Process' name can't be empty.
exit /b 1
)

if "%COND%"=="" (
set CMD_GET_PROC=wmic path win32_process where "Name like '%%%PROC_NAME%%%'" get Processid^^,Caption ^^^| findstr "^%PROC_NAME%"
) else (
set CMD_GET_PROC=wmic path win32_process where "Commandline like '%%%COND%%%' and Name like '%%%PROC_NAME%%%'" get Processid^^,Caption ^^^| findstr "^%PROC_NAME%"
)

set last=
for /f "usebackq tokens=*" %%r in (`%CMD_GET_PROC%`) do (
for %%t in (%%r) do set last=%%t
taskkill /f /pid !!last!
)

其它所作的內容就不贅述了，真的有問題再來問我吧!

友藏內心獨白: 寫完這個batch，功力又提升更多了。

• findstr目標字串長度過長問題
• Why java hang when invoking wmic?

• 2012-09-18 實際使用遇到了block問題。原因是因為透過java程式呼叫時，WMIC其標準輸入導致block，google可以找到相關資訊。最後透過ant呼叫解決。
• 2013-07-30 遇到findstr去過濾process command line長度過長問題。改透過WQL去做filter解決。
• 2013-08-08 找到解決在Windows2003中，透過java程式呼叫wmic block的問題。在command line最後加入<NUL即可解決。Exmaple. wmic xxx ^^^<NUL ^^^| findstr xxxx

---